; First, do a little bit of Blitz housekeeping
NoCli
FindScreen 0

;And load our image in to a blitz shape
im$="Path and filename of your image"
LoadShape 1,im$

;And set up a constant four our return code. This isn't necessary, but keeps things tidy
#BUTPRESSED=1
; Now we'll set up a procedure to initialise the MUI window.

Statement setmui{}

    MUIApplicationTitle        "Lesson2" ;Sets the MUI application name
    MUIApplicationVersion      "$VER: Lesson 2" ; Sets version information
    MUIApplicationCopyright    "(c) 2001, Steve Hargreaves" ;Sets copyright information
    MUIApplicationAuthor       "Steve Hargreaves" ;Sets Author information
    MUIApplicationDescription  "Demonstrate MUI Notification" ;And a description

    MUIApplicationBase         "LESS" ;This should be a unique identifier for your application

    MUIAddApplicationTags #MUIA_Application_SingleTask,True

    MUIAddTags 1,#MUIA_Frame,#MUIV_Frame_Button,#MUIA_InputMode,#MUIV_InputMode_RelVerify
    ; This is an example of adding tags to an object. Tags take the form
    ; Tag to be modified,Value. They are all built in to MUI. In the example
    ; The frame type (in this case a Button frame, but you can use any, (see MUIArea.doc for the list)
    ; and the input mode (this time it's a button type - MUIArea.doc again)
    MUIImageButton 1,1
    ; The syntax - Obj No,Shape No.
    MUICreateWindow 2,"Notify Example","WIND1",1
    MUIAddSubWindow 2
    If MUICreateApplication=False
        End
    EndIf

    MUINotifyApp 1,#MUIA_Pressed,0,#BUTPRESSED

    ; The syntax is Obj No,Event,State/condition,Return Value

    MUINotifyApp 2,#MUIA_Window_CloseRequest,1,#MUIV_Application_ReturnID_Quit

End Statement

;And now the main bit

setmui{}
MUIOpenWindow 2
Repeat
    ev.l=MUIWaitEvent
    Select ev
    Case #BUTPRESSED
        BeepScreen 0

    Case #MUIV_Application_ReturnID_Quit
        End

End Select
Forever